当前位置:首页 » 网站技术 » ASP

Persits.Jpeg(ASPJpeg)组件使用说明

...

我现在用的这个空间经控针测试支持Persits.Jpeg (ASPJpeg) 版本 1.4.0.1
下面就这个组件的功能说明一下:

一、图片缩略

<%
Dim tmStart, tmEnd, demo
tmStart = timer()
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<title>JSP家测试Persits.Jpeg组件</title>
</head>

<body>
<%
Dim Jpeg,Path
Set Jpeg = Server.CreateObject("Persits.Jpeg")
Path = Server.MapPath("images/sogou.gif")
Jpeg.Open Path

' 设置缩略图大小(这里比例设定为50%)
Jpeg.Width = Jpeg.OriginalWidth / 2
Jpeg.Height = Jpeg.OriginalHeight / 2

' 保存缩略图到指定文件夹下
Jpeg.Save Server.MapPath("images/sogou_small.jpg")

Set Jpeg = Nothing
%>

<IMG SRC="images/sogou.gif">
<br>缩略前的图片<br>
<IMG SRC="images/sogou_small.jpg">
<br>
缩略后的图片
<%
tmEnd = timer()
%>
页面执行时间:<font color=blue> <%=CStr(FormatNumber((tmEnd - tmStart),3)*1000)%> </font> 毫秒

</body>
</html>

观看演示:http://www.jspjia.com/sample/01.asp

二、图片水印

<%
Dim tmStart, tmEnd, demo
tmStart = timer()
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<title>图片水印</title>
</head>

<body>
<%
Dim Jpeg,Path
Set Jpeg = Server.CreateObject("Persits.Jpeg")
Path = Server.MapPath("images/google.jpg")
Jpeg.Open Path

' 添加文字水印
Jpeg.Canvas.Font.Color = &HFF0000 '颜色
Jpeg.Canvas.Font.Family = "arial" '字体
Jpeg.Canvas.Font.Bold = True '是否加粗
Jpeg.Canvas.Print 10, 10, "Copyright ? JspJia.Com" '打印坐标x,打印坐标y,需要打印的字符

'图片片框处理
Jpeg.Canvas.Pen.Color = &H000000 '颜色
Jpeg.Canvas.Pen.Width = 2 '画笔宽度
Jpeg.Canvas.Brush.Solid = False '是否加粗处理
Jpeg.Canvas.Bar 1, 1, Jpeg.Width, Jpeg.Height '起始X坐标 起始Y坐标 输入长度 输入高度

Jpeg.Save Server.MapPath("images/googlewater.jpg")

Set Jpeg = Nothing
%>

<IMG SRC="images/google.jpg"><br>水印前<br>
<IMG SRC="images/googlewater.jpg"><br>水印后<br>
<%
tmEnd = timer()
%>
页面执行时间:<font color=blue> <%=CStr(FormatNumber((tmEnd - tmStart),3)*1000)%> </font> 毫



</body>
</html>

演示地址:http://www.jspjia.com/sample/02.asp

三、安全码

安全玛的道理和加水印差不多
<%
'生成安全码的函数
function make_randomize(max_len,w_n) 'max_len 生成长度,w_n:0 可能包含字母,1:只为数字
randomize
for intcounter=1 to max_len
whatnext=int((1-0+1)*rnd+w_n)
if whatnext=0 then
upper=122
lower=97
else
upper=57
lower=48
end if
strnewpass=strnewpass & chr(int((upper-lower+1)*rnd)+lower)
next
make_randomize=strnewpass
end function
%>

'生成安全码的图片。当然你要预先准备一张背景图哦

<%
random_num=make_randomize(4,1) '生成4位数字的安全码
session("random_num")=random_num '为什么调用session,没有session的安全码是完全没有意义的。

Set Jpeg = Server.CreateObject("Persits.Jpeg") '调用组件
Jpeg.Open Server.MapPath("infos/random_pic/random_index.gif") '打开准备的图片
Jpeg.Canvas.Font.Color = &H006699
Jpeg.Canvas.Font.Family = "Arial Black"
Jpeg.Canvas.Font.Bold = false
Jpeg.Canvas.PrintText 0, -2, random_num
jpeg.save Server.MapPath("infos/random_pic/random_index.bmp") '保存
%> <img src="/infos/random_pic/random_index.bmp" border="0" align="absmiddle">

四、图片切割

一直以来,对aspjpeg不了解的人以为是无法用它来进行切割的。
其实有这样的一个方法的
crop x1,y1,x2,y2
切割长方型左上角x坐标,y坐标 右下角x坐标 y坐标
下面我就做一个演示哈

Set Jpeg = Server.CreateObject("Persits.Jpeg")
jpeg.open server.MapPath("/pic/1.gif")
jpeg.width=70
Jpeg.Height = Jpeg.OriginalHeight*70 / jpeg.Originawidth
jpeg.crop 0,0,70,52 '开始切割其实是把超过52象素的下部分去掉
jpeg.save server.MapPath("/temp_pic/small_1.gif") '保存

五、图片合并

我们这里是要把 logo 图片加到 dodge_viper.jpg 图片上去
其实,图片合并的方法也可以用来动态打水印哦

Set Photo = Server.CreateObject("Persits.Jpeg")
PhotoPath = Server.MapPath("images") & "\dodge_viper.jpg"
Photo.Open PhotoPath
Set Logo = Server.CreateObject("Persits.Jpeg")
LogoPath = Server.MapPath("images") & "\clock.jpg"
Logo.Open LogoPath

Logo.Width = 70
Logo.Height = Logo.Width * Logo.OriginalHeight / Logo.OriginalWidth

Photo.DrawImage 0, 0, Logo

Photo.SendBinary

这里用了sendBinary的输出方法。当然,你也可以先保存更改后的dodge_viper.jpg,再输入也可以。我个人不大喜欢用sendBinary方法,在网速慢的时候容易出错。在速度方面也不怎样。

七、更多方法介绍

Canvas.Line(Left, Top, Right, Bottom)
'画一条直线
Canvas.Ellipse(Left, Top, Right, Bottom)
'画出一个椭圆
Canvas.Circle(X, Y, Radius)
'画出一个圆
Canvas.Bar(Left, Top, Right, Bottom)
'画出一个长方形,上面有代码介绍了
Canvas.Font.ShadowColor
'文字阴影颜色
Canvas.Font.ShadowXOffset As Long
'阴影X坐标设定
Canvas.Font.ShadowYOffset As Long
'Y坐标设定
Canvas.Font.BkMode As String
'文字背景

继续阅读
ASP.NET进度条
没有数据时显示GridView表格
ASP.NET中的换行问题解决方案
ASP.NET跳转页面方法比较
ASP.NET内置功能抵御Web攻击
ASP.NET写文件实例
ASP禁用页面缓存的五种方法
ASP.NET页面间值传递方法实例
使用ASP.NET备份和还原SQL Server及Access数据库
发表评论

昵称:
最新评论
暂时没有评论!